Würfeln

Aus ProgrammingWiki

Inhaltsverzeichnis

1 Zufallszahlen
2 Würfeln mit mehreren Würfeln

Zufallszahlen

Wir erzeugen zunächst einzelne Zufallszahlen.

(randomint 100)

Dabei stellen wir fest: (randomint <max>) gibt eine Zufallszahl z zurück mit 0 \le z < max.
Vervollständigen Sie die nachfolgende nullstellige Prozedur, mit der das Würfeln einer Augenzahl z mit 1 \le z \le 6 simuliert werden kann:

(define wuerfelzahl
  (lambda ()
    ...))

(wuerfelzahl)

Wurf mehrerer Würfel

Würfeln mit mehreren Würfeln

Nun wollen wir das gleichzeitige Werfen mehrerer Würfel simulieren. Dabei soll uns nur interessieren, wie oft die Summe aller Augenzahlen auftreten.
Um signifikante Aussagen zu erhalten, muss diese Simulation in großer Anzahl wiederholt werden können.

Lösungsidee

Definiere eine Zählerliste, deren Startwerte Null sind.
Die Position jedes Listenelements entspricht genau der Summe aller geworfenen Augenzahlen.
Nach jedem Wurf wird die Summe aller Augenzahlen gebildet und der Wert des entsprechenden Listenelements um 1 erhöht.
Wiederhole die Simulation in der gewünschten (großen) Anzahl.

Implementation

(define wuerfeln
  (lambda (wuerfel anz)
    (letrec
        ([startliste
          (lambda (pos)
            (if (= pos 0)
                ()
                (cons 0 (startliste (- pos 1)))))]
         [summe
          (lambda (wuerfel)
            (if (= wuerfel 0)
                0
                (+ (wuerfelzahl) (summe (- wuerfel 1)))))]         
         [poszaehlen
          (lambda (ls pos)
            (if (= pos 1) 
                (cons (+ 1 (car ls)) (cdr ls))
                (cons (car ls) (poszaehlen (cdr ls) (- pos 1)))))]
         [zaehlen
          (lambda (ls anz)
            (if (= anz 0)
                ls
                (let ([pos (- (summe wuerfel) wuerfel -1)])
                  (zaehlen (poszaehlen ls pos) (- anz 1)))))])
      (zaehlen (startliste (+ (* 5 wuerfel) 1)) anz))))

(define wuerfelausgabe
  (lambda (wuerfel anz)
    (letrec 
        ([ausgabe
          (lambda (ls pos)
            (if (not (null? ls))
                (begin
                  (display "Augenzahl ") (display pos) (display ":") (display #\tab) (display (car ls))
                  (newline)
                  (ausgabe (cdr ls) (+ pos 1)))))]
         [maximum
          (lambda (ls pos maxpos)
            (if (null? (cdr ls))
                (begin
                  (display "Die Augenzahl ") (display maxpos) 
                  (display " ist mit der Anzahl ") (display (car ls)) (display " am häufigsten vertreten.")
                  (newline))
                (if (> (car ls) (cadr ls))
                    (maximum (cons (car ls) (cddr ls)) (+ pos 1) maxpos)
                    (maximum (cdr ls) (+ pos 1) (+ pos 1)))))]        
         [ergebnis (wuerfeln wuerfel anz)])
      (ausgabe ergebnis wuerfel)
      (maximum ergebnis wuerfel wuerfel)
      (balkendiagramm ergebnis)
      'ok)))

(wuerfelausgabe 10 10000)

Aufgaben

Übertragen Sie die Ergebnisse der Simulation mit 10 Würfeln in eine Tabellenkalkulation.
Untersuchen Sie mit geeigneten Methoden, welche Häufigkeitsverteilung der Augenzahlen vorliegen könnte.