GnomSort

Aus ProgrammingWiki

Archivierte Version vom 2011-05-01T19:59:57+00:00. Aktuelle Version

Inhaltsverzeichnis

1 Algorithmus
2 Effizienz von GnomSort
- 2.1 Average-Case-Experimente
- 2.2 Best- und Worst-Case-Experimente

Algorithmus

Gartenzwerge sortieren Blumentöpfe, die in einer Reihe aufgestellt sind, der Größe nach.
Sie benutzen dazu den folgenden Algorithmus:

Beginne links und vergleiche die beiden ersten Töpfe.
Stehen sie in der richtigen Reihenfolge gehe ein Schritt nach rechts.
Vertausche die beiden Töpfe, wenn sie nicht in der korrekten Reihenfolge stehen, und gehe einen Schritt nach links.

Ist der Schritt nach links nicht möglich, gehe ein Schritt nach rechts.
Wiederhole das Sortieren bis zum letzten Blumentopf.

Die Größe der Blumentöpfe wird mit Zufallszahlen festgelegt:

(define zufallszahl
  (lambda (min max)
    (+ (randomint (- max min -1)) min)))

(define zufallsliste
  (lambda (min max anzahl)
   (if (= anzahl 0)
        ()
        (cons (zufallszahl min max) (zufallsliste min max (- anzahl 1))))))

;GnomSort
(define gnomsort
  (lambda (ls)
    (letrec
        ([sort
          (lambda (ls1 ls2)
            ...])
      (reverse (sort ls ())))))

Ungeordnete Zufallszahlen:

Geordnete Zufallszahlen:

(define ls (zufallsliste 1 1000 100))
(balkendiagramm ls 1)
(define ls-sort (gnomsort ls))
(balkendiagramm ls-sort 2)

Hinweis: Um mehrere Zeichenflächen nutzen zu können, muss die Prozedur balkendiagramm mit einem zusätzlichen Parameter ausgestattet werden, der einer fortlaufenden Nummerierung entspricht:

(balkendiagramm
  <ls>       ; Liste mit Zahlenwerten   
  <nr>)      ; fortlaufende Nummerierung des Balkendiagramms

Effizienz von GnomSort

Average-Case-Experimente

Wir definieren unseren GnomSort-Algorithmus mit einem "eingebauten" (Zeittakt-)Zähler:

(define count 0)

(define gnomsort-aufwand
  (lambda (ls)
    (letrec
        ([sort
          (lambda (ls1 ls2) 
            (cond
              [(null? ls1) ls2]
              [(null? (cdr ls1))
               (set! count (+ 1 count)) ;gib die einelementige Liste zurück
               (cons (car ls1) ls2)]
              [(> (car ls1) (cadr ls1))
               (set! count (+ 1 count)) ;vertausche das n-te Paar und gehe nach links (bzw. nach rechts)
               (if (null? ls2)
                   (sort (cons (car ls1) (cddr ls1)) (cons (cadr ls1) ls2))
                   (sort (cons (car ls2) (cons (cadr ls1) (cons (car ls1) (cddr ls1)))) (cdr ls2)))]
              [else
               (set! count (+ 1 count)) ;gehe nach rechts
               (sort (cdr ls1) (cons (car ls1) ls2))]))])
      (reverse (sort ls ())))))


(define gnomsort-ausgabe
  (lambda (min max anzahl)
    (let ([ls (zufallsliste min max anzahl)])
      (set! count 0)
      (display "Ungeordnete Zufallszahlen:") (newline)
      (display ls) (newline)
      (display "Geordnete Zufallszahlen:") (newline)
      (display (gnomsort-aufwand ls)) (newline)
      (display "Anzahl der Vertauschungen bzw. Bewegungen: ") (display count) (newline)
      'ok)))

(gnomsort-ausgabe 1 1000 20)

Im Weiteren wollen wir uns nur auf die Zählergebnisse unseres "Zeittaktmessers" konzentrieren.
Dazu sollen die Wiederholungen des Experimentes automatisiert werden:

(define gnomsort-mehrfach
  (lambda (min max anzahl whlg)
    (letrec 
        ([summe
          (lambda (n)           
            (if (= n 0)
                0
                (begin
                  (set! count 0)
                  (gnomsort-aufwand (zufallsliste min max anzahl))
                  (+ count (summe (- n 1))))))])     
      (exact->inexact (/ (summe whlg) whlg)))))

(gnomsort-mehrfach 1 1000 20 100)

Schließlich sollen die Ergebnisse unserer empirischen Untersuchung wieder im Balkendiagramm visualisiert werden.

(define experiment
  (lambda (min max anzahl schrittweite whlg)
    (if (< anzahl 1)
        ()
        (append (experiment min max (- anzahl schrittweite) schrittweite whlg)
                (list (gnomsort-mehrfach min max anzahl whlg))))))

Achtung! Mit kleinen Wiederholraten und etwas Geduld experimentieren!

(balkendiagramm (experiment 1 1000 200 5 10) 3)

Die empirischen Untersuchungen zeigen im Mittel offensichtlich einen quadratischen Zeitaufwand von GnomSort.
Es gilt:

average case:	T(n) = \frac{1}{2} \cdot n^2 bzw.
	T(n) = \mathcal{O}(n^2)

Best- und Worst-Case-Experimente

(define gnomsort-spezial
  (lambda (min max anzahl whlg . ls)
    (letrec
        ([anwenden 
          (lambda (zuf-ls ls)
            (if (null? ls)
                zuf-ls
                (apply (car ls) (list (anwenden zuf-ls (cdr ls))))))]
         [summe
          (lambda (n)           
            (if (= n 0)
                0
                (begin
                  (set! count 0)
                  (gnomsort-aufwand (anwenden (zufallsliste min max anzahl) ls))
                  (+ count (summe (- n 1))))))])
       (exact->inexact (/ (summe whlg) whlg)))))

(define experiment-spezial
  (lambda (min max anzahl schrittweite whlg . ls)
    (if (< anzahl 1)
        ()
        (append (apply experiment-spezial min max (- anzahl schrittweite) schrittweite whlg ls)
                (list (apply gnomsort-spezial min max anzahl whlg ls))))))

GnomSort: best-case

GnomSort: worst-case

(balkendiagramm (experiment-spezial 1 1000 200 5 1 gnomsort) 4)
(balkendiagramm (experiment-spezial 1 1000 200 5 5 reverse gnomsort) 5)

GnomSort

Inhaltsverzeichnis

Algorithmus

Effizienz von GnomSort

Average-Case-Experimente

Best- und Worst-Case-Experimente

Suche